#!/usr/bin/perl
############################################################
# mkm -- Make a new manifest file
# Mike Schilli <m@perlmeister.com>, 2002
############################################################

use strict;
use warnings;

use File::Find;

my $VERSION = "1.01";
our $CVSVERSION = '$Revision: 1.4 $';

my @FILES = ();

File::Find::find(sub {
    my $file = $_;

    return unless -f $file;

    (my $fullname = $File::Find::name) =~ s#^\./##;

    return if $fullname =~ /^Makefile$/;
    return if $fullname =~ /^pm_to_blib$/;
    return if $fullname =~ /^Makefile.old$/;
    return if $fullname =~ /\.tar\.gz$/;
    return if $fullname =~ /^blib\//;
    return if $fullname =~ /^CVS\//;
    return if $fullname =~ /\/CVS\//;

    push @FILES, $fullname;
    }, ".");

open FILE, ">MANIFEST" or die "cannot open MANIFEST";
for (@FILES) {
    print FILE "$_\n";
}
close FILE;

=cut

=head1 NAME

    mkm - Make a new MANIFEST file for a Perl module

=head1 DOWNLOAD

_SRC_HERE_

=head1 SYNOPSIS

    mkm

=head1 OPTIONS

=head1 DESCRIPTION

C<mkm> creates a new MANIFEST file for Perl modules. Started from 
the top directory of the module, it locates all project files recursively,
filters out clutter like C<CVS>, C<Makefile.old>, C<blib/> and
overwrites the current C<MANIFEST> file with this new list.

=head1 EXAMPLES

  $ cd Proc-Simple-1.18
  $ mkm

=head1 LEGALESE

Copyright 2002 by Mike Schilli, all rights reserved.
This program is free software, you can redistribute it and/or
modify it under the same terms as Perl itself.

=head1 AUTHOR

2002, Mike Schilli <m@perlmeister.com>